BloGauth

Votre Server est installé, tout s'est bien passé, maintenant nous allons voir comment nous connecter en Admin a notre Server flash media.

Pourquoi se connecter en Admin? Plusieurs raisons, grâce a ce type de connexion nous pouvons ajouter des administrateur locaux qui pourront eux même gérer leur groupe d'application (attribution de vhost). Voir tout les streams utiliser par une application, voir la bande passante utiliser par le Server ou une application, le nombre de connections etc... Bref comme le nom l'indique cela nous permet d'administrer notre Server flash media à quelques exceptions prés. Ici je considère que vous avez installer fms (flash media Server) de manière standard (pas de mapping des répertoire etc..., bref vous avez fait basique). Assez parlé rentrons dans le vif du sujet. Dans l'ordre :

1. établir la connexion en tant qu'Admin
2. récupérer les stats du server
3. récupérer la liste des applications
4. récupérer les stats d'une application

En route pour l'aventure....

Source fla

I ETABLIR LA CONNEXION :

 
/****
*Variable d'identification de l'administrateur
*******/
var server:String="localhost";
var loginAdmin:String = "monLogin";
var passAdmin:String = "monPass";
 
/****
*Creation de la connexion avec le Flash Media Server en tant qu'administrateur et requete pour recuperer la liste des applications situé sur le server.
*******/
var nc:NetConnection = new NetConnection();
nc.onStatus = function(objInfo) {
	if (objInfo.code == "NetConnection.Connect.Success") {
		trace("vous êtes connecté a l'admin de votre flash media server!")
	}
};
nc.connect("rtmp://"+server+":1111/admin", loginAdmin, passAdmin);
 

Ici nous créons une connexion en stipulant le port admin 1111 (attention le port admin as pu être modifier par vos soins lors de l'installation ainsi il faudra bien mettre celui que vous avez déclaré, mais en général c'est bien le port 1111 qui est alloué a l'admin) et l'application "admin", il suffit de rentrer en paramètre votre login et pass admin que vous avez définit lors de votre installation.

SUPER vous voila connecté en admin, ça en jette non? Quoi? Vous voulez voir autre chose? TRES BIEN!!!

II RECUPERATION DES STATS DU SERVER

Voila une information extrêmement utile pour toute personne soucieuse de son server fms…

Grâce a ces information, nous pourrons voir ce qui rentre et ce qui sort, la bande passante utilise, une estimation du processeur et de la mémoire utilise sur le server etc… bref là encore des informations qui peuvent avoir leur pesant d’or

 
function getServerStat() {
	this.onResult = function(objResult) {
		var serverStat:Array = objResult.data;
		for (var i:String in serverStat) {
			//ici on regarde si la propriété est un objet si oui on parcourt ce dernier pour en ressortir les informations
			if (typeof (serverStat[i]) == "object") {
				for (var j:String in serverStat[i]) {
					trace(j+" : "+serverStat[i][j]);
				}
			} else {
				trace(i+" : "+serverStat[i]);
			}
		}
	};
}
nc.call("getServerStats", new getServerStat());

Nous venons de lancer la requête et grâce à "new getServerStat()" nous demandons a notre fms de nous retourner un objet de résultat. La fonction onResult est indispensable pour pouvoir manipuler le résultat renvoyé par le server. L’objet retourné contient une propriété data qui n’est autre qu’un objet (contenant dans ce cas l'objet io qui nous donne des infos sur ce qui rentre et sort) et des propriété concernant l'état du server lui même.

III RECUPERATION DE LA LISTE DES APPLICATIONS

Hé oui ici nous allons voir comment récupérer toute les applications se situant dans votre répertoire d’application du flash media server (en gros on liste les dossiers tout simplement). Rien de plus simple la commande getApps() nous renvoi cette liste !

 
function getListeApps() {
	this.onResult = function(objResult) {
		var listeApps:Array = objResult.data;
		//nous parcourons le tableau qui contient la liste de nos applications
		for (var prop:String in listeApps) {
			trace(prop+" : "+listeApps[prop]);
		}
	}
}
nc.call("getApps", new getListeApps());

IV RECUPERATION DES STATS D’UNE APPLICATION

Nous allons voir ici comment récupérer les stats d’une application. Attention une application n’est pas une instance active, une application peut contenir plusieurs instance de celle-ci, monApplication n’est pas la même chose que monApplication/test par exemple, test étant une instance de l’application mon Application.

Pour ne pas vous perturber quand vous développé une application pour fms dans votre client flash pour vous connecter vous faite :

 
nc.connect( "rtmp://monserveur/ monApplication");

Par défaut fms va créer une instance de monApplication en la nommant _definst_ mais vous pouvez créer autant d’instance que vous voulez juste en précisant le nom de cette dernière :

 
nc.connect( "rtmp://monserveur/ monApplication/test");

Ici nous venons de créer l’instance test de monApplication. Donc pour en revenir à nos moutons nous allons voir comment récupérer les stats d’une application pouvant regrouper de une à mille instances par exemple ;).

 
function AppStat() {
	this.onResult = function(objResult) {
		var statAppResult:Array = objResult.data;
		for (var prop:String in statAppResult) {
			trace(prop+" : "+statAppResult[prop])
		}
	};
}
//nom etant le nom de l'application que vous voulez sonder.
nc.call("getAppStats", new AppStat(), nom);

Le principe est le même que pour les autres requête a une exception nous devont cette fois ci passer le nom de l'application en parametre.

Le but de ce billet est de vous familiariser avant tout avec l'administration fms et de manipuler les objet de retour de fms. Je vous conseille vivement de vous rendre sur le livedoc de macromedia pour avoir une vue complète des possibilité de l'administration de votre flash media server.

livedoc Flash Media Server